faa/faa_pix/faa_pix.ino

//
// wirelessly connected cloud (based on a LPWAN, called ESP-NOW)
//

//
//   this module will be an esp-now node in a group.
//       like, a bird in a group of birds.
//
//   esp-now @ esp8266 w/ broadcast address (FF:FF:FF:FF:FF:FF)
//       always broadcasting. everyone is 'talkative'.
//

//============<identities>============
#define MY_GROUP_ID       (8000)
#define MY_ID             (MY_GROUP_ID + 101)
#define MY_SIGN           ("PIXEL")
//============</identities>============

//============<parameters>============
#define WIFI_CHANNEL 1
//============</parameters>===========

//arduino
#include <Arduino.h>

//message types
#include "message.h"

//espnow
#include <ESP8266WiFi.h>
#include <espnow.h>

//task
#include <TaskScheduler.h>
Scheduler runner;

//-*-*-*-*-*-*-*-*-*-*-*-*-
#include <Adafruit_NeoPixel.h>
#define PIXEL_COUNT 8
uint32_t PIXELS[PIXEL_COUNT] = {0, };
uint8_t pix_brightness = 255;
uint8_t p_pix_brightness = 255;
#define PIXEL_PIN   12 // D6
Adafruit_NeoPixel strip(PIXEL_COUNT, PIXEL_PIN, NEO_GRB + NEO_KHZ800);
extern Task pixel_task;
void pixel() {

  ///
  if (pixel_task.isFirstIteration()) {
    strip.begin();                                              // INITIALIZE NeoPixel strip object (REQUIRED)
    strip.show();                                               // Turn OFF all pixels ASAP
  }

  ///
  if (p_pix_brightness != pix_brightness) {
    p_pix_brightness = pix_brightness;
    strip.setBrightness(pix_brightness);                          // Set BRIGHTNESS to about 1/5 (max = 255)
  }

  //
  for (int idx = 0; idx < PIXEL_COUNT; idx++) {
    strip.setPixelColor(idx, PIXELS[idx]);                      //  Set pixel's color (in RAM)
  }

  //
  strip.show();                                                 //  Update strip to match
}
Task pixel_task(20, TASK_FOREVER, &pixel, &runner, true); // every 20 ms
//*-*-*-*-*-*-*-*-*-*-*-*-*

//task #0 : blink led
#define LED_PERIOD (11111)
#define LED_ONTIME (1)
#define LED_GAPTIME (222)
#define LED_PIN 2
extern Task blink_task;
void blink() {
  //
  static int count = 0;
  count++;
  //
  switch (count % 4) {
  case 0:
    digitalWrite(LED_PIN, LOW);     // first ON
    blink_task.delay(LED_ONTIME);
    break;
  case 1:
    digitalWrite(LED_PIN, HIGH);     // first OFF
    blink_task.delay(LED_GAPTIME);
    break;
  case 2:
    digitalWrite(LED_PIN, LOW);     // second ON
    blink_task.delay(LED_ONTIME);
    break;
  case 3:
    digitalWrite(LED_PIN, HIGH);     // second OFF
    blink_task.delay(LED_PERIOD - 2* LED_ONTIME - LED_GAPTIME);
    break;
  }
}
Task blink_task(0, TASK_FOREVER, &blink, &runner, true); // -> ENABLED, at start-up.

// on 'Note'
void onNoteHandler(Note & n) {
  //is it for me?
  if (n.id == MY_GROUP_ID || n.id == MY_ID) {
    //
    int intensity = (int)n.velocity;
    if (intensity < 0) intensity = 0;
    if (intensity > 255) intensity = 255;
    pix_brightness = intensity;
    //
    int idx = (int)n.pitch;
    if (idx < 0) idx = 0;
    if (idx > PIXEL_COUNT - 1) idx = PIXEL_COUNT - 1;
    PIXELS[idx] = strip.Color(n.x1, n.x2, n.x3);
  }
}

// on 'receive'
void onDataReceive(uint8_t * mac, uint8_t *incomingData, uint8_t len) {

  //
  Serial.write(incomingData, len);

  // open => identify => use.
  if (incomingData[0] == '{' && incomingData[len - 1] == '}' && len == (sizeof(Hello) + 2)) {
    Hello hello("");
    memcpy((uint8_t *) &hello, incomingData + 1, sizeof(Hello));
    //
    Serial.println(hello.to_string());
  }

  // open => identify => use.
  if (incomingData[0] == '[' && incomingData[len - 1] == ']' && len == (sizeof(Note) + 2)) {
    Note note;
    memcpy((uint8_t *) &note, incomingData + 1, sizeof(Note));
    onNoteHandler(note);
    //
    Serial.println(note.to_string());
  }
}

// on 'sent'
void onDataSent(uint8_t *mac, uint8_t sendStatus) {
  char buff[256] = "";
  sprintf(buff, "Delivery failed! -> %02X:%02X:%02X:%02X:%02X:%02X",  mac[0],  mac[1],  mac[2],  mac[3],  mac[4],  mac[5]);
  if (sendStatus != 0) Serial.println(buff);
}

//
void setup() {

  //led
  pinMode(LED_PIN, OUTPUT);

  //input
  pinMode(D1, INPUT);
  pinMode(D2, INPUT);
  pinMode(D3, INPUT);
  //
  pinMode(D5, INPUT);
  pinMode(D6, INPUT);
  pinMode(D7, INPUT);
  pinMode(D8, INPUT);

  //serial
  Serial.begin(115200);
  delay(100);

  //info
  Serial.println();
  Serial.println();
  Serial.println("\"hi, i m your postman.\"");
  Serial.println("-");
  Serial.println("- my id: " + String(MY_ID) + ", gid: " + String(MY_GROUP_ID) + ", call me ==> \"" + String(MY_SIGN) + "\"");
  Serial.println("- mac address: " + WiFi.macAddress() + ", channel: " + String(WIFI_CHANNEL));
  Serial.println("-");

  //wifi - disabled
  system_phy_set_max_tpw(0);
  WiFiMode_t node_type = WIFI_STA;
  WiFi.mode(node_type);

  //esp-now
  if (esp_now_init() != 0) {
    Serial.println("Error initializing ESP-NOW");
    return;
  }
  esp_now_set_self_role(ESP_NOW_ROLE_COMBO);
  esp_now_register_send_cb(onDataSent);
  esp_now_register_recv_cb(onDataReceive);
  //
  Serial.println("- ! (esp_now_add_peer) ==> add a 'broadcast peer' (FF:FF:FF:FF:FF:FF).");
  uint8_t broadcastmac[6] = {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF};
  esp_now_add_peer(broadcastmac, ESP_NOW_ROLE_COMBO, 1, NULL, 0);

  Serial.println("-");
  Serial.println("\".-.-.-. :)\"");
  Serial.println();
}

void loop() {
  //
  runner.execute();
  //
}